AE911Truth Petition Summary
Calculation Methodology

Here is a spread sheet I made of the AE911 Truth petition list, copied from the web page.
This was as of May 15, 2013.  The latest one is at www.AE911truth.org
In Excel, you can click on the name to launch your browser to see their Profile details.
I did a Ctrl+F Find search for various top universities.

In June 2013, I was provide a CSV of the Petition List from the AE911Truth Verification Team
for the purposes of doing a summary and database cleanup.  Here are the results of that data.

Degree and University Counting and Tabulating Program

Program in operation

A program was run which looks for synonyms
for example: C.E., Civ.Eng. Civil Eng. and counts them as one degree

The program can distinguish between Brown University (Ivy League in Rhode Island)
and Brown College in Minnesota

Table of Synonyms for Degrees - and Universities

The field names have the word "degree" but can also be used for the synonyms of universities (an after-thought)
The tilde (~) indicates if the Bio field should be used, otherwise just the Title and Degree fields were counted.

X Displey
Order		 Degree
or University		 Unique
Count		 Total Degree0 Count0 Degree1 Count1 Degree2 Count2 Degree3 Count3 Degree4 Count4 Degree5 Count5 Degree6 count6
10 PE ~ 242 242 PE 35 Professional Engineer 3 Prof. Eng. 0 P.E. 204 ProfE 0 ProfEng 0   0
20 CE~ 163 170 CE 5 Civil Engineer 44 Civ. Eng. 1 C.E. 1 CivE 0 CivEng 1 Civil Engineering 118
30 BSEE ~ 157 160 BSEE 73 B.S.E.E. 15   0   0 Electrical Engineering 72   0   0
40 B. Arch 110 114 B. Arch 43 B.Arch 25 BArch 13 BA Architecture 5 B .Arch. 1 Bachelor of Architecture 24 Bachelors of Architecture 3
50 MArch 69 78 MArch 13 M.Arch 16 M. Arch. 21 M. Architecture 3 Masters of Architecture 7 Master's of Architecture 1 Master of Architecture 17
60 ME ~ 70 70 ME 10 BSME 60   0   0   0   0   0
70 BSCE 52 54 BSCE 34 B.S.C.E. 14 B. CE 0 B. C.E. 0 B Sc Mechanical Engineering 1 B.S.E. 5   0
80 MSCE 8 9 MSCE 6 MCE 1 Masters of Civil Engineering 0   0 Master of Civil Engineering 2   0   0
90 BS ~ 513 515 BS 176 B.S. 331 B. S. 8   0   0   0   0
100 MS ~ 191 194 MS 71 MSc 11 M.S. 78 M.Sc. 12 M. Arch 22   0   0
110 PhD ~ 77 90 PhD 50 Ph.D. 39 Ph. D. 1   0   0   0   0
120 AIA ~ 87 87 AIA 86 A.I.A. 1 A. I. A. 0   0   0   0   0
130 FAIA 7 7 FAIA 7 F.A.I.A. 0   0   0   0   0   0
140 FAICP 1 1 FAICP 1   0   0   0   0   0   0
150 Berkeley ~ 41 41 Berkeley 41 UCBerkeley 0 Berkley 0 USB 0   0   0   0
160 MIT ~ 17 17 MIT 12 M.I.T. 5 Massachusettts Institute of Te 0   0   0   0   0
170 Harvard 16 16 Harvard 16   0   0   0   0   0   0
180 Carnegie Mellon 15 18 Carnegie Mellon 11 Carnegie-Mellon 6 CMU 1   0   0   0   0
190 Stanford ~ 14 14 Stanford 14   0   0   0   0   0   0
200 Columbia U ~ 14 14 Columbia U 9 Columbia U. 1 Columbia Univ. 1 Columbia University 2 Columbia Univ 1   0   0
210 Cornell 11 11 Cornell 11   0   0   0   0   0   0
220 Texas Tech ~ 11 11 Texas Tech 11 TTU 0 Texas Technical 0   0   0   0   0
225 Worcester ~ 7 8 Worcester 4 WPI 4   0   0   0   0   0
227 U Penn 6 7 U Penn 2 Univ. of Penn. 0 University of Pennsylvania 3 UPenn 2   0   0   0
230 Iowa State ~ 6 6 Iowa State 6 Iowa S.U. 0   0   0   0   0   0
240 Yale 5 5 Yale 5   0   0   0   0   0   0
250 Northwestern 4 4 Northwestern 4 NWU 0   0   0   0   0   0
270 Cal Tech 3 3 Cal Tech 0 Cal. Tech. 0 California Institute of Technology 0 CalTech 3   0   0   0
280 Dartmouth 3 3 Dartmouth 3   0   0   0   0   0   0
290 Princeton 3 3 Princeton 3   0   0   0   0   0   0
300 Brown U ~ 3 3 Brown U 1 Brown U. 2 Brown Univ 0 Brown Univ. 0 Brown University 0   0   0
320 Oxford ~ 0 0 Oxford 0   0   0   0   0   0   0
330 UDC 0 0 UDC 0 Univ. Dist Colm 0 University of the District of Columbia 0 University Dist. Columbia 0   0   0   0
340 MCSE 0 0 MCSE 0   0   0   0   0   0   0
350 Colgate 0 0 Colgate 0   0   0   0   0   0   0
360 Hobart 0 0 Hobart 0 HWS 0   0   0   0   0   0
370 Villanova 2 2 Villanova 2 Villenova 0   0   0   0   0   0
380 Maharishi 0 0 Maharishi 0   0   0   0   0   0   0
390 U at Buffalo ~ 4 6 U of Buffalo 0 Univ of Buffalo 1 University of Buffalo 0 Univ at Buffalo 0 U. Buffalo 1 Buffalo 4   0
400 Harvey Mudd 7 14 Harvey Mudd 7 Harvey Mudd 7 Harvey Mud 0   0   0   0   0
410 Albany 12 12 Albany 12   0   0   0   0   0   0

Excel format: Degrees.xls

Program to calculate counts - for any programmers who might be interested

* CountAE - Counter for Architects & Engineers for 9/11 Truth Petition list
* Rick Shaddock
* This program counts how many times various degrees, titles, or Universities appear
* It accommodates synonyms such as "Civil Engineer", "Civ.Eng.", "CivEng", "C.E."

* Parameters
* X = include the XMISC signers (General)
* P = list Petition Signers instead of running the count do pList
* S = Search for a String
* ~ = not use the Bio field (which may lead to false positives)

parameter cXMisc

clear
do case
case empty(cXMisc) && no param or ""
 lXMisc =.f. && exclude them / only count A & Es
case upper(cXMisc) $'LP'
 do pList && Search for a String
 return
case upper(cXMisc) ='S'
 do pString && Search for a String
 return
otherwise && "X" or "x'
 lXMisc =.t. && include the General / Misc degrees
endcase

if used('DEGREES')
 select DEGREES
else
 if file('DEGREES.DBF')
  select 0
  use DEGREES
 else
  wait window 'Cannot find DEGREES.DBF'
  suspend
 endif
endif
set filter to
replace all DEGREES.X with ''
set order to Order
go top
browse last normal nowait
if 2 =WCommand('OK;Cancel', 'TR')
 return
endif

* See if some Degrees were selected
locate for not empty(DEGREES.X)
if found() =.t.
 lDegreesX =.t.
 set filter to not empty(DEGREES.X)
else
 lDegreesX =.f.
 set filter to
endif

if used('AE911TRUTH')
 select AE911TRUTH && AE911TRUTH_SUPPORTERS___VERIFIED___2013_06_03
else
 select 0
 use ? alias AE911TRUTH
endif
set filter to
replace all X with '' && clear the previous run markings

if lXMisc =.t. && all inclusive
 cFilterAEX =''
else && Only AEs
 cFilterAEX =' and Category # "XMISC"'
endif
browse last normal nowait

select DEGREES
* Blank out previous values
replace all Count with 0, Total with 0, Count0 with 0, Count1 with 0, Count2 with 0, Count3 with 0, Count4 with 0, Count5 with 0, Count6 with 0
go top
browse last normal nowait

cFilterAE =''
cDegree_ =''
scan && DEGREES
if '~' $ DEGREES.Degree && Tilde is code for not counting Bio
 lBio =.f.
else
 lBio =.t.
endif
wait window 'Counting ' +trim(DEGREES.Degree) +'...' nowait

select AE911TRUTH
set filter to
replace all AE911TRUTH.X with ''

select DEGREES
*? cFilterAE
pCountCode('Degree0', 'Count0')
pCountCode('Degree1', 'Count1')
pCountCode('Degree2', 'Count2')
pCountCode('Degree3', 'Count3')
pCountCode('Degree4', 'Count4')
pCountCode('Degree5', 'Count5')
pCountCode('Degree6', 'Count6')

select AE911TRUTH
set filter to not empty(AE911TRUTH.X)
count to nCountAE

select DEGREES
replace DEGREES.Count with nCountAE
endscan

select AE911TRUTH
do case
case lDegreesX and lXMisc =.t. && particular search
 set filter to not empty(AE911TRUTH.X)
case lDegreesX and lXMisc =.f.
 set filter to not empty(AE911TRUTH.X) and Category # 'XMISC'
case lXMisc =.f. && Only AEs
 set filter to Category # "XMISC"
case lXMisc =.t. && all inclusive
 set filter to
otherwise
 wait window 'Impossible'
endcase
go top
browse last normal nowait

select DEGREES
replace all Total with Count0 +Count1 +Count2 +Count3 +Count4 +Count5 +Count6
go top
browse last normal nowait

wait window 'Done' nowait
* Done


procedure pCountCode
 * Count a code such as "Brown U."
 parameters fDegree_, fCount_
 cDegree_ =alltrim(upper(&fDegree_))
 if not empty(cDegree_)
  wait window 'Counting ' +trim(cDegree_) +'...' nowait
  select AE911TRUTH
  cFiltAE=[(' ' +cDegree_ +' ' $ upper(Title +Degree ] +iif(lBio,[+Bio], []) +[) or ] +;
  ['-' +cDegree_ +' ' $ upper(Title +Degree ] +iif(lBio,[+Bio], []) +[) or ] +;
  [',' +cDegree_ +' ' $ upper(Title +Degree ] +iif(lBio,[+Bio], []) +[) or ] +;
  [' ' +cDegree_ +',' $ upper(Title +Degree ] +iif(lBio,[+Bio], []) +[) or ] +;
  ['-' +cDegree_ +',' $ upper(Title +Degree ] +iif(lBio,[+Bio], []) +[) or ] +;
  [upper(Title) =cDegree_ +' ' or ] +;
  [upper(Title) =cDegree_ +',' or ] +;
  [upper(Degree)=cDegree_ +' ' or ] +;
  [upper(Degree)=cDegree_ +',')] +cFilterAEX
  set filter to &cFiltAE
  replace all X with 'X'
  count to nCount_ 
 
  select DEGREES
  replace &fCount_ with nCount_
 else
  * don't count blank entries
 endif
 return


procedure pList
 release window TEMP.TXT
 select AE911TRUTH
 *set filter to not empty(X) and upper(Category) # 'XMISC'
 set safety off
 list off trim(Firstname)+ ' '+trim(Lastname) +', ' +trim(Title) +', ' +trim(Degree)+', ' +trim(City) +', ' +trim(State) to Temp.txt
 set safety on
 clear
 go top
 browse last normal nowait
 do count
 modify file Temp.txt nowait

procedure pString
 * Simple search
 release cString
 public cString
 cString =GetValue('cString', 'Enter cString')
 if '~' $ cString
  lBio =.f.
 else
  lBio =.t.
 endif
 if '!' $ cString
  lBioOnly =.t.
 else
  lBioOnly =.f.
 endif
 if '\' $ cString && Bar the X's
  lXMisc =.f. && exclude XMISC
 else
  lXMisc =.t. && count everyone
 endif

 * Remove codes
 cString =strtran(cString, '~', '')
 cString =strtran(cString, '!', '')
 cString =strtran(cString, '\', '')

 cString =alltrim(upper(cString))

 select AE911TRUTH
 do case
 case lBioOnly =.t.
  cFilter =[not "&cString" $ upper(Title) and not "&cString" $ upper(Degree) and "&cString" $ upper(Bio)]
 case lBio =.t.
  cFilter =[("&cString" $ upper(Title) or "&cString" $ upper(Degree) or "&cString" $ upper(Bio))]
 otherwise
  cFilter =[("&cString" $ upper(Title) or "&cString" $ upper(Degree))]
 endcase 

 if lXMISC =.t.
  && cFilter as is
 else
  cFilter =cFilter +[ and not Category ='XMISC']
 endif

 set filter to &cFilter
 release window TEMP.TXT
 set safety off
 list off trim(Firstname)+ ' '+trim(Lastname) +', ' +trim(Title) +', ' +trim(Degree)+', ' +trim(City) +', ' +trim(State) to Temp.txt
 set safety on
 clear
 go top
 browse last normal nowait
 do count
 modify file Temp.txt nowait
 return

 
 

AEPetitionAnalysis.xls

Countae.PRG

CountAE.txt

CountAll.xls

Methodology

Notes - errors found in the database that need fixing

Richard Gage should mention Berkeley Univ. for his B.Arch. in his bio
Charles Sing charlie brown title
Hoeflich Enggineering bio
Chris Shaddock degree science
Tony Szamboti should mention Villanova U